Implementing an alternative JIT provider for PostgreSQL

Mon, 09 Oct 2023 00:00:00 +0000

Just in time compilation is added to PostgreSQL since the version of 11. The default JIT provider for PostgreSQL is based on LLVM. PostgreSQL allows user to use an alternative JIT provider by setting the jit_provider GUC parameter¹. The pluggable JIT interface is very easy to use and I’ve successfully built two prototypes, one emits C codes² and the other one emits assembly codes³ using the AsmJit library⁴. In this post, I’ll give a brief introduction to the existing LLVM JIT provider and show you how to implement the prototype that emits C codes. It’s fun and easy.

First Attempt on Writing a Clang Plugin

Thu, 13 Apr 2023 00:00:00 +0000

Updated on 2024/03/28: Recently, I learned a new tool called CodeQL. The AST matcher introduced in this post can be re-written into the following query.

suspicious-control-flow-stmt-in-PG_TRY.ql (Click me to view the content)

/**
 * @name Find suspicious control flow stmt in PG_TRY()
 * @kind problem
 * @problem.severity warning
 * @id postgresql/suspicious-control-flow-stmt-in-pg-try
 */

import cpp

predicate pgTryCatchBlocks(Stmt tryBlock, Stmt catchBlock) {
  exists(IfStmt ifStmt, FunctionCall sigsetjmpCall, BinaryOperation op, Literal zero |
    sigsetjmpCall.getTarget().hasName("__sigsetjmp") and
    ifStmt.getCondition().(BinaryOperation) = op and
    op.getOperator() = "==" and
    op.hasOperands(sigsetjmpCall, zero) and
    /* Reduce false positives. */
    ifStmt.isAffectedByMacro() and
    tryBlock = ifStmt.getThen() and
    catchBlock = ifStmt.getElse()
  )
}

predicate suspiciousReturn(Stmt stmt) { stmt instanceof ReturnStmt }

predicate suspiciousBreak(Stmt stmt, Stmt tryBlock) {
  stmt instanceof BreakStmt and
  not exists(Loop loop |
    loop = tryBlock.getAChild+() and
    loop.getAChild+() = stmt
  ) and
  not exists(SwitchStmt switch |
    switch = tryBlock.getAChild+() and
    switch.getAChild+() = stmt
  )
}

predicate suspiciousContinue(Stmt stmt, Stmt tryBlock) {
  stmt instanceof ContinueStmt and
  not exists(Loop loop |
    loop = tryBlock.getAChild+() and
    loop.getAChild+() = stmt
  )
}

predicate suspiciousGoto(Stmt stmt, Stmt tryBlock) {
  stmt instanceof GotoStmt and
  not exists(LabelStmt label |
    label.getName() = stmt.(GotoStmt).getName() and
    label = tryBlock.getAChild+()
  )
}

from Stmt tryBlock, Stmt suspiciousControlFlowStmt
where
  pgTryCatchBlocks(tryBlock, _) and
  suspiciousControlFlowStmt = tryBlock.getAChild*() and
  (
    suspiciousReturn(suspiciousControlFlowStmt) or
    suspiciousBreak(suspiciousControlFlowStmt, tryBlock) or
    suspiciousContinue(suspiciousControlFlowStmt, tryBlock) or
    suspiciousGoto(suspiciousControlFlowStmt, tryBlock)
  )
select suspiciousControlFlowStmt, "Found suspicious control flow statements in PG_TRY() block"

Updated on 2024/01/06: My fix got merged in 57d00517 and I received a fancy PostgreSQL challenge coin!

PostgreSQL on @higuoxing's site

Implementing an alternative JIT provider for PostgreSQL

First Attempt on Writing a Clang Plugin